Просмотр исходного текста страницы Настройка локального вращения

[[Category:Решения]]
[[Category:Papyrus]]
[[Category:Скриптинг]]
Функция [[SetAngle_-_ObjectReference|SetAngle]] вращает объект относительно глобальных осей, а не локальных осей объекта. Это значит, что если вы, например, хотите описать в скрипте движение корабля, то у вас нет возможности учитывать тангаж и крен (вращение вдоль осей x и y).

Для вращения объекта вдоль локальных осей, используйте эту функцию:

<source lang="papyrus">
Function SetLocalAngle(Float LocalX, Float LocalY, Float LocalZ)
	Float AngleX = LocalX * Math.Cos(LocalZ) + LocalY * Math.Sin(LocalZ)
	Float AngleY = LocalY * Math.Cos(LocalZ) - LocalX * Math.Sin(LocalZ)
	SetAngle(AngleX, AngleY, LocalZ)
EndFunction
</source>

Итак, если вы хотите, чтобы корабль сделал крен на 15 градусов относительно его левой стороны, в то время, как его нос поднимается корабля на 10 градусов, при направлении корабля в 135 градусов, то нужно использовать:

<source lang="papyrus">SetLocalAngle(-10, 15, 135)</source>

Предполагается, что функция будет находиться на заскриптованном объекте, и при вызове будет двигать только этот объект.  Вы можете с легкостью сделать её глобальной внеся небольшие изменения:

<source lang="papyrus">
Function SetLocalAngle(ObjectReference MyObject, Float LocalX, Float LocalY, Float LocalZ) Global
	Float AngleX = LocalX * Math.Cos(LocalZ) + LocalY * Math.Sin(LocalZ)
	Float AngleY = LocalY * Math.Cos(LocalZ) - LocalX * Math.Sin(LocalZ)
	MyObject.SetAngle(AngleX, AngleY, LocalZ)
EndFunction
</source>

Очевидно, что параметр ''MyObject'' сделан для объекта, который вы хотите повернуть.


Следующий скрипт заставляет объект постоянно вращаться:

<source lang="papyrus">
Scriptname RotatingObject extends ObjectReference  

Float Property RotationSpeed = 20.0 Auto ; Скорость вращения

Event OnInit()
	SetMotionType(4)  ; это необходимо, если скрипт присоединен к объекту с havok-физикой
 	OnTranslationAlmostComplete()
EndEvent

Event OnCellLoad()
	OnTranslationAlmostComplete()
EndEvent

Event OnUpdate()
	OnTranslationAlmostComplete()
EndEvent

Event OnTranslationAlmostComplete()
	If ( Is3DLoaded() )
		Float AngleZ = GetAngleZ() + 120
		If ( AngleZ >= 360 )
			AngleZ = AngleZ - 360
		EndIf
		TranslateTo(GetPositionX(), GetPositionY(), GetPositionZ(), GetAngleX(), GetAngleY(), AngleZ, 0.0, RotationSpeed)
	Else
		RegisterForSingleUpdate(0.1)
	EndIf
EndEvent
</source>