Просмотр исходного текста страницы Extending Scripts (Papyrus)

=Обзор=
Наследование скрипта ('''англ.''' inheritance) - это действие в котором берется за основу скрипт, который делает практически все что вам нужно, и затем переопределяются какие-то из его событий или функций, чтобы добиться нужной вам цели без редактирования оригинального скрипта. То есть наш скрипт будет "наследовать" методы и свойства другого, и далее вы расширяете его функционал. Аналогичное есть в ООП языках программирования, например PHP, Java, C# и др.

=Терминология=
*Parent: Родитель. Оригинальный скрипт, функционал которого будет наследован.
*Child: Потомок. Скрипт, который наследует функционал своего родителя.
*Inherit: Наследник. Когда скрипт-потомок получает от своего родителя методы и свойства без их изменения, то он "наследует" ('''англ.''' inherit) их.
*Override: Переопределение. Когда скрипт-потомок меняет поведение определенных в родителе методов и/ил свойств, создавая их новую версию, он "переопределяет"('''англ.''' override) те, что были у родителя.

=Как наследовать=
Наследование скрипта это просто: В верхней части скрипта, после "scriptname x", вы добавляете "extends y" где Y это название скрипта, который вы хотите наследовать.

Пример:
<source lang="papyrus">
Scriptname SpikeTrap extends Trap
</source>

В этом случае, скрипт "SpikeTrap" наследует функционал скрипта "Trap". Вы можете рассматривать "это", как некое взаимоотношение. В данном случае "ловушка с шипами" создается на основе "ловушки".

=Что могут делать скрипты с наследованием=
==Функции и события==
Скрипт-потомок имеет доступ ко всем функциям и событиям своего родителя. Любая функция или событие, которые вы не реализуете в скрипте-потомке наследуется потомком. Если функция или событие реализуется в родителе, и вы вы реализуете её так же и в потомке, то та, что в потомке переопределит ту, что в родителе, и любые вызовы этой функции или события будут использовать версию потомка вместо версии родителя. Обратите внимание, что при реализации функции или события в потомке, вы '''должны''' соответствовать параметрам и типу возвращаемых данных родителя, вместе с именем. В противном случае, скрипт не скомпилируется.

Пример:
<source lang="papyrus">
Scriptname ParentScript

Function MyFunction()
  Debug.Trace("Parent MyFunction!")
EndFunction

Function MyOtherFunction()
  Debug.Trace("Parent MyOtherFunction!")
EndFunction
</source>
<br/>
<source lang="papyrus">
Scriptname ChildScript extends ParentScript

Function MyFunction()
  Debug.Trace("Child MyFunction!")
EndFunction
</source>

*Прицепляем скрипт-потомок к чему-либо и затем вызываем функцию MyFunction на нем:
 Child MyFunction!
Здесь потомок переопределяет и заменяет функцию родителя на свою.

*Прицепляем скрипт-родитель к чему-либо и затем вызываем функцию MyFunction на нем:
 Parent MyFunction!
В этом случае скрипт-потомок не существует, так что старый функционал родителя остается нетронутым.

*Прицепляем оба скрипта к чему-либо и затем вызываем на нем MyOtherFunction:
 Parent MyOtherFunction!
Потомок не переопределяет эту функцию, так что используется исходная функция родителя.

===Вызов функции у родителя===
Если вы хотите вызвать функцию у скрипта-родителя и проигнорировать эту функцию в вашем собственном скрипте, вы можете использовать специальную переменную "parent". Обратите внимание, что эта переменная работает только на текущем скрипте - вы не можете использовать её для вызова чего-либо на другом скрипте. Чаще всего такой подход используется тогда, когда вы хотите, чтобы ваш скрипт делал минимальные настройки чего-то прежде чем дать родителю делать всю тяжелую работу.

Пример:
<source lang="papyrus">
Scriptname ChildScript extends ParentScript

Function MyFunction()
  Debug.Trace("Child MyFunction!")
  parent.MyFunction()
EndFunction
</source>

*Вызов MyFunction на этом скрипте-потомке, прицепленном к объекту:
 Child MyFunction!
 Parent MyFunction!
Обратите внимание, что переменная parent принудительно вызывает родительскую версию функции, а затем вызывает версию потомка.

==Структуры==
Структуры в скрипте-потомке соединяются со структурами из скрипта-родителя. Функции в той же структуре в потомке будут переопределять функции в родителе - и все структуры будут соединены.
*Родитель имеет структуру, потомок не имеет: В данной структуре будут использованы родительские функции.
*Потомок имеет структуру, родитель не имеет: В данной структуре будут использованы функции потомка.
*Родитель имеет функцию в структуре, потомок не имеет: Будет использоваться версия родителя.
*Потомок имеет функцию в структуре, родитель не имеет: Будет использоваться версия потомка.
*Оба имеют функцию в одинаковых структурах: Будет использоваться версия потомка.

==Свойства==
Свойства в родительском скрипте ведут себя так же, как если бы они были свойствами скрипта-потомка. Однако, вы не можете переопределить их у потомка для своих целей. Если вы попытаетесь это сделать, то компилятор начнет ругаться.

Пример:
<source lang="papyrus">
Scriptname ParentScript

int Property MyProperty Auto
</source>
<br/>
<source lang="papyrus">
Scriptname ChildScript extends ParentScript

Function MyFunction()
  Debug.Trace("MyProperty = " + MyProperty)
EndFunction
</source>

Обратите внимание, что MyProperty используется в скрипте-потомке, как бы если бы она в нем существовала, хотя она существует в родительском скрипте.

==Переменные==
Переменные имеют зону видимости private и не могут просматриваться другими скриптами, включая скрипты-родители или потомки.
Имея переменную с таким же именем, как и у родителя, скрипт будет полностью скрывать родительскую переменную, при обращении к переменной в функции потомка. Функция у родителя будет использовать свою собственную переменную.

Пример:
<source lang="papyrus">
Scriptname ParentScript

int MyVar = 1

Function MyFunction()
  Debug.Trace("Parent MyVar = " + MyVar)
EndFunction
</source>
<br/>
<source lang="papyrus">
Scriptname ChildScript extends ParentScript

string MyVar = "Hello World!"

Function MyFunction()
  Debug.Trace("Child MyVar = " + MyVar)
  parent.MyFunction()
EndFunction
</source>

*Вызов MyFunction в скрипте-потомке, прикрепленном к объекту:
 Child MyVar = Hello World!
 Parent MyVar = 1
Обратите внимание, что каждый скрипт может видеть только его локальную копию переменной.


==Примечание по преобразованию объектов в тип родителя==

Скажем у меня есть скрипт <code>Horse</code> а так же скрипт, который наследует <code>Horse</code>, называемый <code>WarHorse</code>. Вкратце, лошадь будет убегать, если увидит волка, но боевая лошадь вместо этого может начать его атаковать:

<source lang="papyrus">
Scriptname Horse extends Actor

Event OnSeeWolf()
  Debug.Notification("Лошадь убежала.")
EndEvent
</source>

<source lang="papyrus">
Scriptname WarHorse extends Horse

Event OnSeeWolf()
  Debug.Notification("Лошадь атакует волка.")
EndEvent
</source>

У меня есть актер <code>MeanWarhorse</code> с присоединенным скриптом <code>WarHorse</code>. Рассмотрим следующий блок скрипта:

<source lang="papyrus">
(MeanWarhorse as Horse).OnSeeWolf()
</source>

При вызове функции данным способом, какое сообщение я увижу, "Лошадь убежала" или "Лошадь атакует волка"?:

Оказывается, даже если вы приведете объект к типу родителя (Horse), '''объект все равно будет вести себя в зависимости от скрипта, который был присоединен к нему в CK.'''  Таким образом, в нашем случае, будет показано сообщение "Лошадь атакует волка".  Данную вещь очень полезно знать, например если вам нужно передать сообщение объекту, но вы не знаете его точный тип.

Допустим у нас есть другой тип лошади, называемый <code>CartHorse</code>. Лошадь с повозкой не может убежать, поскольку привязана к повозке, поэтому она будет стоять на месте, и выглядеть нервной.

<source lang="papyrus">
Scriptname CartHorse extends Horse

Event OnSeeWolf()
  Debug.Notification("Лошадь нервничает.")
EndEvent
</source>

У меня есть зачарование на волке с эффектом типа "плащ" (cloak), которое делает следующее:

<source lang="papyrus">
Scriptname WolfFearEffect extends ActiveMagicEffect

Event OnEffectStart(Actor akTarget, Actor akCaster)
  (akTarget as Horse).OnSeeWolf()
EndEvent
</source>

При данной настройке, когда боевая лошадь будет находится под эффектом страха от волка, то станет атаковать его.  При применении эффекта к лошади с повозкой, она будет стоять на месте, нервничая, и когда другой тип лошади попадет под данный эффект, то такая лошадь убежит.

Примечание: Если в данном случае у меня оба скрипта <code>WarHorse</code> и <code>CartHorse</code> присоединены к одному и тому же актеру, то актер будет рассматриваться как один из двух типов, видимо выбирается случайно.



=Обычные функции и события=

Перечисленные здесь функции и события присутствуют во всех скриптах на Papyrus, и для них не нужно наследовать другой.

==Функции-члены==
*Function [[GotoState - All Scripts|GotoState]](string asNewState)
**Меняет состояние данного скрипта на переданное в аргументе
*string Function [[GetState - All Scripts|GetState]]()
**Возвращает состояние, в котором находится скрипт в данный момент

==События==
*Event [[OnBeginState]]()
**Выполняется, как только был выполнен переход в данное состояние
*Event [[OnEndState]]()
**Выполняется, как только скрипт собирается перейти в другое состояние

[[Category:Papyrus]]