Просмотр исходного текста страницы Light Switch

[[Файл:Symbol_error.png]] '''Статья не закончена!'''
[[Category:Незаконченная статья]]

[[Category:Решения]]

== Установка ==
Скрипт на этой станице может использоваться для автоматического включения/выключения набора источников света в зависимости от времени суток. Он содержит 2 свойства, имеющих значения по-умолчанию, но их можно настроить в Creation Kit
# LightsOffTime
#* Время, в которое все источники света должны быть выключены. По-умолчанию установлено как 7:00 утра.
# LightsOnTime
#* Время, в которое все источники света должны быть включены. По-умолчанию установлено как 18:00 вечера.

Для работы этого скрипта, вам нужно либо создать маркер, или выбрать один из источников света как "главный"(master), и установить его у всех других источников света в [[Reference#Enable_Parent|enable parent]]. Теперь, прицепите скрипт, что ниже, к маркеру или главному источнику света. Если вы не хотите использовать значения по-умолчанию, то либо измените их в скрипте, или переназначьте в Creation Kit.

== Скрипт ==
<source lang="papyrus">ScriptName TimedLightSwitch extends ObjectReference
{Управляет набором источников света главным маркером-родителем,
к которому прицеплен этот скрипт для включения и выключения света в указанное время дня
в свойствах LightsOffTime и LightsOnTime}

float Property LightsOffTime = 7.0 auto
{Время суток, в которое свет должен выключаться}
float Property LightsOnTime = 18.0 auto
{Время суток, в которое свет должен включаться}

float Function GetCurrentHourOfDay() global
{Возвращает текущее время суток в часах с полуночи}

	float Time = Utility.GetCurrentGameTime()
	Time -= Math.Floor(Time) ; Удаляет кусочек "предыдущего, переданного игрой значения прошедших дней"
	Time *= 24 ; Конвертирует часть дня в число часов
	Return Time
 
EndFunction

Function RegisterForSingleUpdateGameTimeAt(float GameTime)
{Регистрирует для одиночного события UpdateGameTime при следующем вхождении
указанного игрового времени GameTime (в часах с полуночи)}

	float CurrentTime = GetCurrentHourOfDay()
	If (GameTime < CurrentTime)
		GameTime += 24
	EndIf

	RegisterForSingleUpdateGameTime(GameTime - CurrentTime)

EndFunction

Event OnInit()

	If (GetCurrentHourOfDay() > LightsOffTime)
		GoToState("LightsOff")
	Else
		GoToState("LightsOn")
	EndIf

EndEvent

State LightsOff

	Event OnBeginState()
		Disable()
		RegisterForSingleUpdateGameTimeAt(LightsOnTime)
	EndEvent

	Event OnUpdateGameTime()
		GoToState("LightsOn")
	EndEvent

EndState

State LightsOn

	Event OnBeginState()
		Enable()
		RegisterForSingleUpdateGameTimeAt(LightsOffTime)
	EndEvent

	Event OnUpdateGameTime()
		GoToState("LightsOff")
	EndEvent

EndState</source>

== Объяснение работы скрипта ==
Этот скрипт состоит из 2 пользовательских функций, первая - событие [[OnInit]], и вторая - [[States_(Papyrus)|состояния]], каждая со своими персональными событиями [[OnBeginState]] и [[OnUpdateGameTime_-_Form|OnUpdateGameTime]].

Функции описаны в самом скрипте, но если вдруг что-то не ясно:
=== GetCurrentHourOfDay ===
Эта функция использует глобальную функцию скрипта [[Utility Script|Utility Script]], [[GetCurrentGameTime_-_Utility|GetCurrentGameTime]], и некоторые математические манипуляции, для получения текущего времени текущего дня, как число между 0.0 и 24.0

=== RegisterForSingleUpdateGameTimeAt ===
Эта функция работает как вариант функции [[RegisterForSingleUpdateGameTime_-_Form|RegisterForSingleUpdateGameTime]]. Отличие в том, что в том время, как RegisterForSingleUpdateGameTime принимает длительность в качестве параметра, эта пользовательская функция принимает в качестве параметра время в которое нужно произвести update.

Так, например, если бы я передал 7.0 в качестве её параметра, то в следующий раз это будет уже 7:00 утра в Skyrim, this object will have the native event [[OnUpdateGameTime_-_Form|OnUpdateGameTime]] called on it.

=== OnInit ===
This event should pretty much always be used to set up your script in whatever ways are required that cannot be done when initialising properties or variables. All that's required here is that the correct state is selected depending on the current time in-game when this event runs.

If the lights should be off, then the script enters the "LightsOff" state, whereas if they should be on, then the script enters the "LightsOn" state.

=== States ===
The two states are nearly identical, and work sort of like mirror images of one another. Each state, when it begins, changes the enable state of the marker or master light (and therefore all other lights), and registers for a single update in game time at the time at which the state needs to change, as set by the two properties of this script.

When that time is reached, the OnUpdateGameTime event is called, which switches the script to the other state, and its OnBeginState event will run.

== Расширяем работу скрипта ==
Ключевой функцией в этом скрипте являются состояния(states). Specifically, that they both use the OnBeginState native event to set everything that needs to be set, so that the lights can be turned on or off simply by changing the state of the script. By taking advantage of this, it wouldn't be particularly difficult to, say, change the script so that the lights' state is toggled when the scripted object is activated:

=== Переключение света вручную ===
<source lang="papyrus">ScriptName ManualLightSwitch extends ObjectReference
{Controls a set of lights with a master enable parent
marker (EnableMarker) and a switch with this script
attached to turn on and off when the switch is activated}

ObjectReference Property EnableMarker auto
{The marker set as the enable parent of all the lights}

Event OnInit()

	If (EnableMarker.IsDisabled())
		GoToState("LightsOff")
	Else
		GoToState("LightsOn")
	EndIf

EndEvent

State LightsOff

	Event OnBeginState()
		EnableMarker.Disable()
	EndEvent

	Event OnActivate(ObjectReference akActionRef)
		GoToState("LightsOn")
	EndEvent

EndState

State LightsOn

	Event OnBeginState()
		EnableMarker.Enable()
	EndEvent

	Event OnActivate(ObjectReference akActionRef)
		GoToState("LightsOff")
	EndEvent

EndState</source>