Просмотр исходного текста страницы States (Papyrus)

=Обзор=
Скрипты работают в различных состояниях(''англ.'' states) - но одновременно скрипт может находиться только в одном состоянии. Выбор, какой код нужно выполнить при вызове функции или событии, происходит в зависимости от состояния, в котором находится скрипт.

=Определение состояний=
Определить состояние в скрипте очень просто, для этого создайте блок состояния, как следующий:
<source lang="papyrus">
State MyState
  ; Различные функции здесь
EndState
</source>

Если вы хотите, чтобы ваш скрипт начал работу в определенном состоянии, впишите "auto" в начале блока состояния:
<source lang="papyrus">
Auto State StartHere
  ; Функции здесь
EndState
</source>

=='Пустое состояние'==
'Пустое состояние'(''англ.'' empty state) является неявным состоянием, в котором каждая функция '''не''' заключена внутри блока состояния.
<source lang="papyrus">
Function MyFunction()
  ; Эта функция внутри 'пустого состояния'
EndFunction

State MyState
  Function MyFunction()
    ; Эта функция внутри состояния MyState
  EndFunction
EndState
</source>

=Определение функций/событий внутри состояний=
Для определение функции или события внутри состояния, просто вставьте функцию или событие внутрь блока состояния.
<source lang="papyrus">
State MyState
  Function SpecialFunction()
    ; Эта функция внутри состояния MyState
  EndFunction
EndState
</source>

Пожалуйста, обратите внимание: функция или событие должны быть объявлены в 'пустом состоянии' с тем же типом возвращаемых данных и тем же типом параметров, или компилятор начнет жаловаться. Это связано с тем, как игра решает функцию и событие, вызванные во время выполнения скрипта.
<source lang="papyrus">
Function SampleFunction(int myParameter)
  ; Код здесь
EndFunction

State SampleState
  Function SampleFunction(int aParameter)
    ; Эта функция в порядке - так как тип параметра такой же, как и в 'пустом состоянии'
  EndFunction

  Function OtherFunction()
    ; Ошибка! Функция OtherFunction не существует в 'пустом состоянии'
  EndFunction
EndState

State OtherState
  int Function SampleFunction(int myParameter)
    ; Ошибка! У SampleFunction тип возвращаемого значения не совпадает с типом в 'пустом состоянии'
  EndFunction
EndState

State YetAnotherState
  Function SampleFunction(int myParameter, float parameter2)
    ; Ошибка! У SampleFunction параметры не совпадают с теми, что в 'пустом состоянии'
  EndFunction
EndState
</source>

Для вашего удобства, события, которые могут получать различного рода скрипты, уже были определены для вас в пустом состоянии, внутри скриптов, которые вы наследуете (то есть ObjectReference, Actor, и т.д.). Таким образом, вы не должны определять события в пустом состоянии, поэтому все, что нужно сделать, это изменить событие в одном конкретном случае.

=Как выбираются функции=
Когда кто-то вызывает функцию, или объект получает событие, нужная функция вычисляется следующим образом:
#Если скрипт имеет функцию в его текущем состоянии, то вызывает её
#Если скрипт наследует другой скрипт, у которого есть функция в его текущем состоянии, то вызывает её
#Если скрипт имеет функцию в 'пустом состоянии', то вызывает её
#Если скрипт наследует другой скрипт, у которого есть функция в 'пустом состоянии', то вызывает её

Если вкратце, то функции внутри состояний переопределяют функции внутри 'пустого состояния', и функции в новых скриптах переопределяют те, что есть в скриптах, которые они наследуют.

=Как установить состояние скрипта=
Установить состояние в скрипте просто, для этого вызовите [[GotoState - All Scripts|GotoState]](string asStateName) с названием состояния в которое хотите перейти в виде строки. Будет иметь место следующая последовательность событий:
#Событие [[OnEndState]] передается в скрипт для состояния, которое было ранее.
#Состояние переключается на запрашиваемое
#Событие [[OnBeginState]] передается в скрипт для состояния, в которое вошел скрипт.

Имя состояния, в которое входит скрипт не чувствительно к регистру. Если вы хотите перейти в 'пустое состояние', то впишите пустую строку: "".

Так же - вызов функции [[GotoState - All Scripts|GotoState]] не закончит вашу функцию - она все равно будет продолжать работать, так что это вполне приемлемо, чтобы просто изменить состояние вашего объекта в течение определенного куска кода и изменить его обратно, когда закончите.

<source lang="papyrus">
Function MyFunction()
  GotoState("TurnOffActivate")
  ; Произвести кучу долгих действий
  GotoState("")
EndFunction

State TurnOffActivate
  Event OnActivate(ObjectReference akTriggerRef)
    ; Ничего не делать
  EndEvent
EndState
</source>

=Как получить состояние скрипта=
Получить состояние скрипта тоже просто, вызовите функцию [[GetState - All Scripts|GetState]](), которая возвратит название состояние в виде строки, в котором в данный момент находится скрипт. Обратите внимание, что регистр названия состояния в первую очередь зависит от вызова функции, которая устанавливает состояние, и сравнение строк является '''чувствительным к регистру''', так что будьте аккуратнее при сравнении. (В будущем, возможно у нас появится возможность сравнивать строки, которые игнорируют регистр, чтобы сделать этот процесс проще - но что касается текущей ситуации, будьте внимательней)

=Советы и хитрости=
*Если вы хотите выключить событие или функцию находясь в определенном состоянии, то определите это событие или функцию в этом состоянии и оставьте его пустым. Это особенно полезно, если вы хотите чтобы игнорировались какие-то события по активации находясь по среди какого-то процесса.
*Если использование всего одного состояния одновременно сильно ограничивает вас, то помните, что вы всегда можете прицеплять множество скриптов к одному и тому же объекту - и каждый скрипт может иметь свое, отдельное состояние! Это может помочь вам при более сложных операциях. Конечно, вы также можете опираться только на инструкции с оператором if, а также с помощью собственных переменных состояния.
*Так как названия состояний являются строковыми данными, то во время запуска вы можете создавать конструкции используя оператор "+". Например, вы можете определить "State1", "State2", и так далее, и применять их следующим образом:
<source lang="papyrus">
Function GotoNumberedState(int number)
  GotoState("State" + number)
EndFunction
</source>

=Заключение=
Состояния - это мощный и достаточно простой способ изменить поведение вашего скрипта, без необходимости писать громоздкие участи кода в инструкциях с оператором if, или другой сложный код. Иногда проблемы, которые кажутся слишком сложными или хлопотными могут стать легче с творческим использованием состояний!

[[Category:Papyrus]]